strComputer = "." 'her har jeg valgt lokal computer
strfile = "C:\\Users\\XYZ\\Documents\\eventlog.txt" 'lokal sti til filen der skal overvåges
ventetid = 10 'antal sekunder mellem hvert check

Const ForReading = 1
Const cdoSendUsingPickup = 1
Const cdoSendUsingPort = 2
Const cdoAnonymous = 0
Const cdoBasic = 1
Const cdoNTLM = 2

Set objFSO = CreateObject("Scripting.FileSystemObject")

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colMonitoredEvents = objWMIService.ExecNotificationQuery _
("SELECT * FROM __InstanceModificationEvent WITHIN " & ventetid & " WHERE TargetInstance ISA 'CIM_DataFile' and TargetInstance.Name='" & strfile & "'")

Do
Set objLatestEvent = colMonitoredEvents.NextEvent
Set objFile = objFSO.OpenTextFile(strfile, ForReading)

Do Until objFile.AtEndOfStream
strLine = objFile.ReadLine
Loop

objFile.Close

sendpost(strLine)
Loop



sub sendpost(tekst)
'der er mange muligheder når man skal sende mail, her er et eksempel på afsendelse via tdc

Set objMessage = CreateObject("CDO.Message")

objMessage.Subject = "HEJ" 'Emne på mailen
objMessage.From = """MIG"" <XYZ@gmail.com>" 'Afsender
objMessage.To = "XYZ@gmail.com" 'Modtager


objMessage.TextBody = tekst

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'SMTP server
objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

'brugernavn på afsendermail
objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "USERNAME"

'koden til afsendermail
objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "PASSWORD"

'port der bruges til afsendelse, port 25 er blokeret de fleste steder derfor bruger man den alternative port 587
objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60


objMessage.Configuration.Fields.Update
objMessage.Send

end sub